X:10721
T: COTILLION No. 3. tune 1
C:
%R: jig
N: This is version 2, for ABC software that understands diminuendo notation.
U: Q=!diminuendo(!
U: q=!diminuendo)!
B: Elias Howe "The Musician's Companion" Part 1 1842 p.72 #1
S: http://imslp.org/wiki/The_Musician's_Companion_(Howe,_Elias)
Z: 2015 John Chambers <jc:trillian.mit.edu>
M: 6/8
L: 1/8
F:http://roaringjelly.org/~jc/music/book/EliasHowe/MusiciansCompanionP1/10721%3DCotillion_No_3_tune_1-V2.abc	 2025-03-14 021150 UT
K: F
% - - - - - - - - - - - - - - - - - - - - - - - - -
!p!c |\
c>dc caf | d2B B2d | c>dc caf | ef^f g2c |\
c>dc caf | dBA Bcd | cfa {a}gfg | fca f2 H|]
!ff!a |\
agf fed | e2a a2a | agf bge | ^cd^d efg |\
agf fed | e2g bag | fga gfe | deQf qed"^D.C."c |]
K: Bb
f |\
bag fed | g2e cdB | AB=B cde | de=e fga |\
bag fed | cgf edc | BAG FGA | (c3 "^D.C."B2) |]
% - - - - - - - - - - Dance description - - - - - - - - - -
%%begintext align
%% First 4 right and left,
%% balance and turn partners,
%% ladies chain,
%% promenade 4,
%% side couples the same.
%%endtext
% - - - - - - - - - - - - - - - - - - - - - - - - -
%%sep 1 1 300